view PKGBUILD @ 19:2095af12cd4a

New upstream release 1.2.1-rc.1
author Buildbot <buildbot@kalessin.fr>
date Sun, 12 Feb 2017 21:57:03 +0000
parents 63e9b0dba7a0
children 0ed196e8df8a
line wrap: on
line source

# Maintainer: Louis Opter <kalessin@kalessin.fr>

pkgname=lightsd
pkgver=1.2.1~rc.1
# This will have - instead of ~ for rc versions:
_lightsdver=1.2.1-rc.1
pkgrel=1
epoch=1
pkgdesc="Daemon to control your LIFX smart bulbs via a JSON-RPC API"
arch=("i686" "x86_64")
url="https://www.github.com/lopter/lightsd/"
license=("GPL3")
depends=("libevent>=2.0.19")
optdepends=(
    "python: to run the interactive lightsc.py example client"
    "ipython: makes lightsc.py more user-friendly"
)
makedepends=("cmake>=2.8.11")
source=("https://downloads.lightsd.io/releases/lightsd-1.2.1-rc.1.tar.gz")
sha256sums=("ec420247fd3bf28f1c43ce325f97d55dd44bd05eef4b785fe9773ea5bc65fdf9")
install=lightsd.install

build() {
    cd "$srcdir/$pkgname-$_lightsdver"

    cmake .                         \
        -DCMAKE_BUILD_TYPE=RELEASE  \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DLGTD_RUNTIME_DIRECTORY=/run/lightsd

    make
}

check() {
    cd "$srcdir/$pkgname-$_lightsdver"

    make test
}

package() {
    cd "$srcdir/$pkgname-$_lightsdver"

    make DESTDIR="$pkgdir/" install
}