view PKGBUILD @ 22:249aa1e5110d

New upstream release 1.2.1-rc.4
author Buildbot <buildbot@kalessin.fr>
date Sun, 12 Feb 2017 23:44:00 +0000
parents ed25f4b38f85
children 833341e9791d
line wrap: on
line source

# Maintainer: Louis Opter <kalessin@kalessin.fr>

pkgname=lightsd
pkgver=1.2.1~rc.4
# This will have - instead of ~ for rc versions:
_lightsdver=1.2.1-rc.4
pkgrel=1
epoch=1
pkgdesc="Daemon to control your LIFX smart bulbs via a JSON-RPC API"
arch=("i686" "x86_64")
url="https://www.github.com/lopter/lightsd/"
license=("GPL3")
depends=("libevent>=2.0.19")
optdepends=(
    "python: to run the interactive lightsc.py example client"
    "ipython: makes lightsc.py more user-friendly"
)
makedepends=("cmake>=2.8.11")
source=("https://downloads.lightsd.io/releases/lightsd-1.2.1-rc.4.tar.gz")
sha256sums=("b46401bc97bb3570c5ef72b0b1492eb74ced1c5b5c576ccb62d92a1f5da8980d")
install=lightsd.install

build() {
    cd "$srcdir/$pkgname-$_lightsdver"

    cmake .                         \
        -DCMAKE_BUILD_TYPE=RELEASE  \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DLGTD_RUNTIME_DIRECTORY=/run/lightsd

    make
}

check() {
    cd "$srcdir/$pkgname-$_lightsdver"

    make test
}

package() {
    cd "$srcdir/$pkgname-$_lightsdver"

    make DESTDIR="$pkgdir/" install
}